home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / sh0x / sh06b.d64 / cent'hardcpy src (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1995-03-30  |  5.2 KB  |  169 lines
  1. 10 ;++++++++++++++++++++++++++++++++
  2. 20 ;+++++                      +++++
  3. 30 ;+++++ HARDCOPY FUER        +++++
  4. 40 ;+++++ CENTRONICS DRUCKER   +++++
  5. 50 ;+++++   (STAR SG)          +++++
  6. 60 ;+++++ AM USER-PORT         +++++
  7. 70 ;++++++++++++++++++++++++++++++++
  8. 80 ;+++++                +++++++++++
  9. 90 ;+++++ VON            +++++++++++
  10. 100 ;+++++ RICHARD GRESEK +++++++++++
  11. 110 ;+++++                +++++++++++
  12. 120 ;++++++++++++++++++++++++++++++++
  13. 130 .LI1,3
  14. 140 .BA$7000
  15. 150 ;
  16. 160 ;
  17. 170 ;++++++++++++++++++++++++++++++++
  18. 180 ;AUSRECHNEN DER     +++++++++++++
  19. 190 ;STARTADRESSE DER   +++++++++++++
  20. 200 ;BITMAP,PRUEFEN     +++++++++++++
  21. 210 ;OB GRAPHIC EIN     +++++++++++++
  22. 220 ;++++++++++++++++++++++++++++++++
  23. 230 START LDA$D018;BITS 12-13
  24. 240  AND#$0C;DER BITMAP
  25. 250  ASL;INS HI-BYTE
  26. 260  ASL
  27. 270  ASL
  28. 280  ASL
  29. 290  STANBY+2
  30. 300  LDA$DD00;BITS14-15 AUS CIA2 HOLEN
  31. 310  LSR
  32. 320  RORNBY+2;INS HI-BYTE SCHIEBEN
  33. 330  LSR
  34. 340  RORNBY+2
  35. 350  LDANBY+2;BITS 1-2 DER CIA2 LOW-AKTIV
  36. 360  EOR#$C0;DESHALB UMKEHREN MIT EOR #%1100 0000
  37. 370  STANBY+2;UND ZURUCK INS HI-BYTE DES BITMAPZEIGER
  38. 380  LDA#00
  39. 390  STANBY+1;LO-BYTE DES BITMAPZEIGER = 0
  40. 400  LDA$D011;BIT5=1 =>HI-RES GRAPHIC EIN=> AUSDRUCKEN
  41. 410  AND#32
  42. 420  BNEBEGIN
  43. 430  RTS;BIT5=0 >ZURUCK INS HAUPTPROGRAMM
  44. 440 ;++++++++++++++++++++++++++++++++
  45. 450 ;HAUPTPROGRAMM   ++++++++++++++++
  46. 460 ;++++++++++++++++++++++++++++++++
  47. 470 BEGIN SEI;INTERRUPT ABSCHALTEN
  48. 480  LDA#$35;GANZES RAM BIS AUF I/O
  49. 490  STA01;EINBLENDEN
  50. 500  LDA#$FF;PORT B CIA2 AUF AUGANG
  51. 510  STA$DD03
  52. 520  LDA#<(ZEABST+3);ENDADRESSE
  53. 530  LDY#>(ZEABST+3)
  54. 540  STACONTL+1
  55. 550  STYCONTH+1
  56. 560  LDA#<(ZEABST);STARTADRESSE
  57. 570  LDY#>(ZEABST);DER BYTEFOLGE FUER ZEILENABSTAND 8/72 INCH
  58. 580  JSRSTROUT;BYTEFOLGE AUF PARALLEL-PORT AUSGEBEN
  59. 590  LDA#25;25 ZEILEN*40 SPALTEN
  60. 600  STAZEILE
  61. 610 ZEI LDA#40
  62. 620  STASPALTE
  63. 630 SPA LDA#8;8 BYTE IN JEDEM KAESTCHEN
  64. 640  STABYZ
  65. 650 BY LDY#8
  66. 660 NBY LDA$6000;BYTE AUS BITMAP HOLEN
  67. 670 LOOP LDX#01;+++++++++++++++++++++++++++++++++++++++
  68. 680 LOO ROL;BIT NR.X INS CARRY
  69. 690  DEX
  70. 700  BNELOO;+++++++++++++++++++++++++++++++++++++++
  71. 710 ST ROLSCHL;CARRY INS AKTUELLE BYTE EINFUEGEN
  72. 720  INCNBY+1;+++++++++++++++++++++++++++++++++++++++
  73. 730  BNEWE;BITMAPZEIGER ERHOEHEN
  74. 740  INCNBY+2;+++++++++++++++++++++++++++++++++++++++
  75. 750 WE DEY;SCHON 8 BIT ZUSAMMEN?
  76. 760  BNENBY;NEIN >NAECHSTES BYTE HOLEN
  77. 770  INCLOOP+1;NAECHSTE BITSPALTE
  78. 780  SEC
  79. 790  LDANBY+1;+++++++++++++++++++++++++++++++++++++++++++++++
  80. 800  SBC#8;BITMAPZEIGER AUF BYTE NR.1 DER NAECHSTEN SPALTE
  81. 810  STANBY+1;SETZEN
  82. 820  LDANBY+2
  83. 830  SBC#00
  84. 840  STANBY+2;+++++++++++++++++++++++++++++++++++++++
  85. 850  INCST+1;ZEIGER AUF AKTUELLES BYTE IM AUSGABESTRING
  86. 860  BNEWE1;   ERHOEHEN
  87. 870  INCST+2;+++++++++++++++++++++++++++++++++++++++
  88. 880 WE1 DECBYZ;ALLE 8 BYTE DES KAESTCHENS FERTIG?
  89. 890  BNEBY;NEIN=>SPRUNG
  90. 900  LDA#01;1.BITSPALTE DER NAECHSTEN SPALTE
  91. 910  STALOOP+1
  92. 920  CLC;+++++++++++++++++++++++++++++++++++++++
  93. 930  LDANBY+1;BITMAPZEIGER AUF 1.BYTE DER NAECHSTEN SPALTE
  94. 940  ADC#8;STELLEN
  95. 950  STANBY+1
  96. 960  LDANBY+2
  97. 970  ADC#00
  98. 980  STANBY+2;+++++++++++++++++++++++++++++++++++++++
  99. 990  DECSPALTE;ZEILE FERTIG?
  100. 1000  BNESPA;NEIN >NEACHSTE SPALTE
  101. 1010  LDA#<(ZEABST);++++++++++++++++++++++++++++++++++++++++
  102. 1020  LDY#>(ZEABST);GRAPHIC-EINSCHALTSEQUENZ SCHICKEN
  103. 1030  STACONTL+1;(VOR JEDER ZEILE)
  104. 1040  STYCONTH+1
  105. 1050  LDA#<(EINSCH)
  106. 1060  LDY#>(EINSCH)
  107. 1070  JSRSTROUT;++++++++++++++++++++++++++++++++++++++++
  108. 1080  LDA#<(SCHL+$140)
  109. 1090  STACONTL+1;ZUSAMMENGESTELLTE GRAPHICZEILE
  110. 1100  LDA#>(SCHL+$140)
  111. 1110  STACONTH+1;AUF EINMAL AUSGEBEN
  112. 1120  LDA#<(SCHL)
  113. 1130  STAST+1
  114. 1140  LDY#>(SCHL)
  115. 1150  STYST+2
  116. 1160  JSRSTROUT;+++++++++++++++++++++++++++++++++++++++
  117. 1170  LDA#13;RETURN AUF DRUCKER SCHICKEN (NEUE ZEILE)
  118. 1180  JSRCOUT
  119. 1190  DECZEILE;ALLE ZEILEN FERTIG?
  120. 1200  BNEZE;NEIN>NAECHSTE ZEILE
  121. 1210  LDA#$37;BASIC+KERNAL EINSCHALTEN
  122. 1220  STA01
  123. 1230  CLI;IRQ ZULASSEN
  124. 1240  RTS
  125. 1250 ;++++++++++++++++++++++++++++++++
  126. 1260 ;STROUT-AUSGABE EINES    ++++++++
  127. 1270 ;BELIEBIG LANGEN STRINGS ++++++++
  128. 1280 ;AUF PARALLELPORT        ++++++++
  129. 1290 ;                        ++++++++
  130. 1300 ;++++++++++++++++++++++++++++++++
  131. 1310 STROUT STYLADE+2;HI-BYTE DER STARTADR.
  132. 1320  STALADE+1;LO-BYTE  --"--
  133. 1330 LADE LDA$2000;BYTE DES STRING HOLEN
  134. 1340  JSRCOUT;AUF PORT AUSGEBEN
  135. 1350  INCLADE+1;ZEIGER ERHOEHEN
  136. 1360  BNEWE2
  137. 1370  INCLADE+2
  138. 1380 WE2 LDALADE+2
  139. 1390 CONTH CMP#$41;HI-BYTE DER AKT. ADRESSE=HI-B(ENDADR.)?
  140. 1400  BNELADE;NEIN >WEITER
  141. 1410  LDALADE+1;LO-BYTE DER ADRESSE=LO-B(ENDADR.)?
  142. 1420 CONTL CMP#64
  143. 1430  BMILADE;NEIN >WEITER
  144. 1440  RTS;ZURUECK INS HAUPTPROGRAMM
  145. 1450 ZE JMPZEI
  146. 1460 ;-----------------------------
  147. 1470 EINSCH .BY27,103,5,64,1;SEQUENZ ZUM EINSCHALTEN DES GRAPHICMODUS
  148. 1480 ZEABST .BY27,65,8;ZEILENABSTAND 8/72 INCH
  149. 1490 ;++++++++++++++++++++++++++++++++
  150. 1500 COUT STA$DD01;DATEN AUF LEITUNG
  151. 1510  LDA$DD0D;ICR LOESCHEN
  152. 1520  LDA$DD00;
  153. 1530  AND#$FB;PA2 (STROBE)-SIGNAL
  154. 1540  STA$DD00
  155. 1550  ORA#04;=>ZEICHEN FUER
  156. 1560  STA$DD00;'DATA AUF LEITUNG'
  157. 1570  LDA#$10;FLAG2-BUSY
  158. 1580 WARTE BIT$DD0D;BUSY LOW?
  159. 1590  BEQWARTE;+> NEIN
  160. 1600  RTS
  161. 1610 ;+++++++++++++++++++++++++++++++
  162. 1620 ;   VARIABLEN       ++++++++++++
  163. 1630 ;+++++++++++++++++++++++++++++++
  164. 1640 ZEILE NOP;ZEILENZAEHLER
  165. 1650 SPALTE NOP;SPALTENZAEHLER
  166. 1660 BYZ NOP;BYTEZAEHLER FUER JEDES KAESTCHEN
  167. 1670 ;+++++++++++++++++++++++++++++++
  168. 1680 SCHL NOP;ANFANG DES AUSZUGEBENDEN STRINGS
  169.